<![CDATA[Itug Forum - TUSCRIPT]]> https://forum.itug.de/ Sat, 18 Apr 2026 11:19:26 +0000 MyBB <![CDATA[Daten aus einer TUSTEP-Datei auf mehrere Fremd-Dateien aufteilen]]> https://forum.itug.de/showthread.php?tid=9 Sat, 07 Feb 2026 20:45:29 +0100 ChristianSonder]]> https://forum.itug.de/showthread.php?tid=9 Die Datei ist formatiert und enthält die einzelnen Start- und Endetags für
die Hierarchieebenen jeweils auf einer neuen Zeile:

Code:

<teiCorpus>
    <TEI>
        <!-- Hier das erste TEI-Dokument -->
        ...
    </TEI>
    <TEI>
        <!-- Hier das zweite TEI-Dokument -->
        ...
    </TEI>
</teiCorpus>

Gewünscht ist, dass die einzelnen TEI-Dokumente (alles zwischen <TEI> und </TEI>) in eigene Dateien geschrieben werden.

Vorgehen zum Lösen des Problems: 
Die Datei wird zeilenweile gelesen.
Bei Beginn eines TEI-Dokuments wird mithilfe eines Zählers eine neue Zieldatei angelegt.
Der Inhalt des TEI-Dokuments wird in einer Sternvariable zwischengespeichert.
Beim Ende eines TEI-Dokuments wird in die Zieldatei geschrieben.

Hier ein Musterprogramm zur Lösung:
Code:

#MAKRO
$$ MODE TUSCRIPT, {}
SET quelle = "Hier der Name der Quelldatei"
SET präfix = "Hier das Präfix der Zieldateien"

- Benötigte Variablen
SET n = 0
SET tmp = *
SET ziel = ""

- Anfang und Ende der TEI-Dokumente
BUILD S_TABLE start = "|<TEI |"
BUILD S_TABLE ende = "|</TEI>|"

- Schleife über alle Zeilen der Datei
- Es sollen mindestens eine Millionen Datensätze
- verarbeitet werden, bei Bedarf diesen Wert erhöhen.
ACCESS daten: READ/RECORDS $quelle, s.z/u, zeile
LOOP/1000001
  
   - Es wird bei jedem Schleifendurchlauf ein
   - neuer Datensatz eingelesen, bis zum Ende
   - der Datei (oder bis zur Grenze der Schleife)
   READ/NEXT/EXIT daten
  
   - Wenn ein neues TEI-Dokument beginnt,
   - die Sternvariable tmp für den Inhalt
   - der nächsten Datei leeren, hochzählen
   - und die neue Datei erstellen
   IF (zeile .CT. start) THEN
      SET tmp = *
      SET n = n + 1
      SET n = CENTER(n, +3, "0")
      SET ziel = "{präfix}_{n}.xml"
      SET status = CREATE($ziel, FDF-O)
   ENDIF

   - Die neue Zeile der Sternvariable hinzufügen
   SET tmp = APPEND(tmp, zeile)

   - Wenn das TEI-Dokument endet,
   - den Inhalt in die neue Datei schreiben
   IF (zeile .CT. ende) THEN
      FILE/ERASE/UTF8 ziel = tmp
   ENDIF

ENDLOOP
ENDACCESS daten
*eof

Komplexität des Algorithmus (vgl. Landau-Notation)
Die Laufzeit beträgt O(n), da alle n Datensätze jeweils einmal gelesen werden müssen.
Der Speicherverbrauch beträgt O(n), da im Worst-Case-Szenario die Quelldatei in den
Zwischenspeicher kopiert wird.


Anmerkung: Wenn Speicherplatz ein Problem darstellt, kann auf das Zwischenspeichern
der Dokumentinhalte in einer Sternvariable verzichtet werden und jede Zeile direkt in
die jeweils neue Datei geschrieben werden. Der Speicherverbrauch wäre dann O(1),
weil nur konstant viel Speicher belegt wird. Allerdings kann dies zu einer erheblichen
Laufzeitverlängerung führen, da nun die Zeilen einzeln statt blockweise geschrieben
werden. Die Laufzeitkomplexität beträgt zwar immer noch O(n), allerdings benötigen
die einzelnen Schreibprozesse mehr Zeit.]]> Die Datei ist formatiert und enthält die einzelnen Start- und Endetags für
die Hierarchieebenen jeweils auf einer neuen Zeile:

Code:

<teiCorpus>
    <TEI>
        <!-- Hier das erste TEI-Dokument -->
        ...
    </TEI>
    <TEI>
        <!-- Hier das zweite TEI-Dokument -->
        ...
    </TEI>
</teiCorpus>

Gewünscht ist, dass die einzelnen TEI-Dokumente (alles zwischen <TEI> und </TEI>) in eigene Dateien geschrieben werden.

Vorgehen zum Lösen des Problems: 
Die Datei wird zeilenweile gelesen.
Bei Beginn eines TEI-Dokuments wird mithilfe eines Zählers eine neue Zieldatei angelegt.
Der Inhalt des TEI-Dokuments wird in einer Sternvariable zwischengespeichert.
Beim Ende eines TEI-Dokuments wird in die Zieldatei geschrieben.

Hier ein Musterprogramm zur Lösung:
Code:

#MAKRO
$$ MODE TUSCRIPT, {}
SET quelle = "Hier der Name der Quelldatei"
SET präfix = "Hier das Präfix der Zieldateien"

- Benötigte Variablen
SET n = 0
SET tmp = *
SET ziel = ""

- Anfang und Ende der TEI-Dokumente
BUILD S_TABLE start = "|<TEI |"
BUILD S_TABLE ende = "|</TEI>|"

- Schleife über alle Zeilen der Datei
- Es sollen mindestens eine Millionen Datensätze
- verarbeitet werden, bei Bedarf diesen Wert erhöhen.
ACCESS daten: READ/RECORDS $quelle, s.z/u, zeile
LOOP/1000001
  
   - Es wird bei jedem Schleifendurchlauf ein
   - neuer Datensatz eingelesen, bis zum Ende
   - der Datei (oder bis zur Grenze der Schleife)
   READ/NEXT/EXIT daten
  
   - Wenn ein neues TEI-Dokument beginnt,
   - die Sternvariable tmp für den Inhalt
   - der nächsten Datei leeren, hochzählen
   - und die neue Datei erstellen
   IF (zeile .CT. start) THEN
      SET tmp = *
      SET n = n + 1
      SET n = CENTER(n, +3, "0")
      SET ziel = "{präfix}_{n}.xml"
      SET status = CREATE($ziel, FDF-O)
   ENDIF

   - Die neue Zeile der Sternvariable hinzufügen
   SET tmp = APPEND(tmp, zeile)

   - Wenn das TEI-Dokument endet,
   - den Inhalt in die neue Datei schreiben
   IF (zeile .CT. ende) THEN
      FILE/ERASE/UTF8 ziel = tmp
   ENDIF

ENDLOOP
ENDACCESS daten
*eof

Komplexität des Algorithmus (vgl. Landau-Notation)
Die Laufzeit beträgt O(n), da alle n Datensätze jeweils einmal gelesen werden müssen.
Der Speicherverbrauch beträgt O(n), da im Worst-Case-Szenario die Quelldatei in den
Zwischenspeicher kopiert wird.


Anmerkung: Wenn Speicherplatz ein Problem darstellt, kann auf das Zwischenspeichern
der Dokumentinhalte in einer Sternvariable verzichtet werden und jede Zeile direkt in
die jeweils neue Datei geschrieben werden. Der Speicherverbrauch wäre dann O(1),
weil nur konstant viel Speicher belegt wird. Allerdings kann dies zu einer erheblichen
Laufzeitverlängerung führen, da nun die Zeilen einzeln statt blockweise geschrieben
werden. Die Laufzeitkomplexität beträgt zwar immer noch O(n), allerdings benötigen
die einzelnen Schreibprozesse mehr Zeit.]]> <![CDATA[Informationen aus einem späteren Datensatz in einen früheren Datensatz einfügen]]> https://forum.itug.de/showthread.php?tid=4 Sun, 01 Feb 2026 20:56:09 +0100 ChristianSonder]]> https://forum.itug.de/showthread.php?tid=4
Es liegt eine TUSTEP-Datei in folgender Form vor:

Code:

<eins>{#}</eins><zwei></zwei>
<eins>{#}</eins><zwei></zwei>
<eins>{#}</eins><zwei></zwei>
<eins>{#}</eins><zwei></zwei>

Nun soll in jeder Zeile in den zweiten Tag die Nummer des ersten Tags der folgenden Zeile eingetragen werden, ohne dass sonst etwas an den Datensätzen geändert wird. In der letzten Zeile soll nichts eingetragen werden, z. B.:

Code:

<eins>1</eins><zwei>2</zwei>
<eins>2</eins><zwei>3</zwei>
<eins>3</eins><zwei>4</zwei>
<eins>4</eins><zwei></zwei>

Lösungsweg:

Die Datei wird zeilenweise von hinten nach vorne gelesen und die zu schreibende Nummer im Zwischenspeichert gemerkt.
Im ersten Satz von hinten wird nichts eingetragen, ab da die jeweils gemerkte Nummer:

Code:

#MAKRO
$$ MODE TUSCRIPT, {}
SET quelle = "Hier der Name der Quelldatei"
SET ziel = "Hier der Name der Zieldatei"
SET daten = FILE(quelle)

- Wir drehen die Reihenfolge der Datensätze um, lesen also von hinten nach vorne
SET daten = REVERSE(daten)

- Wir suchen eine Zahl, die zwischen <eins> und </eins> steht
- {[} = linker Rand; {]} = rechter Rand
BUILD S_TABLE s1 = "|<eins>{[}{#}{]}</eins>|"

- Schleife über alle Datensätze (Zeilen)
- Bei jedem Durchgang wird die aktuelle Zeile aus der Variable daten
- gelöscht (LOOP/CLEAR), die Nummer eingesetzt und dann die so geänderte Zeile
- wieder hinzugefügt. Dadurch spart man sich den Speicher für eine zweite
- Sternvariable.
SET nummer = ""
LOOP/CLEAR zeile = daten
   BUILD X_TABLE x1 = "|<zwei></zwei>|<zwei>{nummer}</zwei>|"
   SET zeile = EXCHANGE(zeile, x1)
   RELEASE X_TABLE x1
   SET daten = APPEND(daten, zeile)

   - Die Nummer wird für den nächsten Durchgang extrahiert
   SET von = SEARCH(zeile, s1, 0, 0, 1, bis)
   SET nummer = EXTRACT(zeile, #von, #bis)
ENDLOOP

- Wir drehen die Reihenfolge wieder und schreiben in die Zieldatei
SET daten = REVERSE(daten)
FILE/ERASE ziel = daten
*eof

Komplexität des Algorithmus (vgl. Landau-Notation)
Die Laufzeit beträgt O(n), da alle n Datensätze jeweils einmal gelesen werden müssen.
Der Speicherverbrauch beträgt O(1), da nur konstant viel Speicher belegt wird.]]>
Es liegt eine TUSTEP-Datei in folgender Form vor:

Code:

<eins>{#}</eins><zwei></zwei>
<eins>{#}</eins><zwei></zwei>
<eins>{#}</eins><zwei></zwei>
<eins>{#}</eins><zwei></zwei>

Nun soll in jeder Zeile in den zweiten Tag die Nummer des ersten Tags der folgenden Zeile eingetragen werden, ohne dass sonst etwas an den Datensätzen geändert wird. In der letzten Zeile soll nichts eingetragen werden, z. B.:

Code:

<eins>1</eins><zwei>2</zwei>
<eins>2</eins><zwei>3</zwei>
<eins>3</eins><zwei>4</zwei>
<eins>4</eins><zwei></zwei>

Lösungsweg:

Die Datei wird zeilenweise von hinten nach vorne gelesen und die zu schreibende Nummer im Zwischenspeichert gemerkt.
Im ersten Satz von hinten wird nichts eingetragen, ab da die jeweils gemerkte Nummer:

Code:

#MAKRO
$$ MODE TUSCRIPT, {}
SET quelle = "Hier der Name der Quelldatei"
SET ziel = "Hier der Name der Zieldatei"
SET daten = FILE(quelle)

- Wir drehen die Reihenfolge der Datensätze um, lesen also von hinten nach vorne
SET daten = REVERSE(daten)

- Wir suchen eine Zahl, die zwischen <eins> und </eins> steht
- {[} = linker Rand; {]} = rechter Rand
BUILD S_TABLE s1 = "|<eins>{[}{#}{]}</eins>|"

- Schleife über alle Datensätze (Zeilen)
- Bei jedem Durchgang wird die aktuelle Zeile aus der Variable daten
- gelöscht (LOOP/CLEAR), die Nummer eingesetzt und dann die so geänderte Zeile
- wieder hinzugefügt. Dadurch spart man sich den Speicher für eine zweite
- Sternvariable.
SET nummer = ""
LOOP/CLEAR zeile = daten
   BUILD X_TABLE x1 = "|<zwei></zwei>|<zwei>{nummer}</zwei>|"
   SET zeile = EXCHANGE(zeile, x1)
   RELEASE X_TABLE x1
   SET daten = APPEND(daten, zeile)

   - Die Nummer wird für den nächsten Durchgang extrahiert
   SET von = SEARCH(zeile, s1, 0, 0, 1, bis)
   SET nummer = EXTRACT(zeile, #von, #bis)
ENDLOOP

- Wir drehen die Reihenfolge wieder und schreiben in die Zieldatei
SET daten = REVERSE(daten)
FILE/ERASE ziel = daten
*eof

Komplexität des Algorithmus (vgl. Landau-Notation)
Die Laufzeit beträgt O(n), da alle n Datensätze jeweils einmal gelesen werden müssen.
Der Speicherverbrauch beträgt O(1), da nur konstant viel Speicher belegt wird.]]> <![CDATA[Alle Datensätze einer TUSTEP-Datei in einem Datensatz zusammenführen]]> https://forum.itug.de/showthread.php?tid=3 Wed, 28 Jan 2026 17:18:45 +0100 ChristianSonder]]> https://forum.itug.de/showthread.php?tid=3 Eine Frage aus der TUSTEP Nutzergemeinde: Ich möchte alle Sätze einer Tustep-Datei in einen einzigen Satz schreiben, ohne dabei mit AA den Abschnittsanfang angeben zu müssen. Geht das?

Mit TUSCRIPT ist das sehr einfach möglich:

1. Laden des Datei-Inhalts in eine Sternvariable:

Code:

SET daten = FILE(quelle)


2. Reduzieren der Sternvariable auf eine einfache Variable mit der Funktion JOIN:

Code:

SET daten = JOIN(daten, "")

Anmerkung: Man kann auch Trennzeichen angeben, z. B. " " oder ";" oder eben nichts "".

3. Speichern des Variablen-Inhalts in eine Datei

Code:

FILE/ERASE ziel = daten


Hier ein vollständiges Musterprogramm:

Code:

#MAKRO
$$ MODE TUSCRIPT, {}
SET quelle = "Hier der Name der Quelldatei"
SET ziel = "Hier der Name der Zieldatei"
SET daten = FILE($quelle)
SET daten = JOIN(daten, "")
FILE/ERASE ziel = daten
*eof

Sehr nützlich in diesem Zusammenhang sind die TUSCRIPT-Funktionen RECORDS und SIZE, um zu kontrollieren, ob ein JOIN wie erwartet funktioniert hat.
Mit diesen kann die Anzahl der Datensätze einer Datei abgefragt werden (Records) oder die Anzahl der Zeilen in einer Sternvariable (SIZE), z. B.:

Code:

#MAKRO
$$ MODE TUSCRIPT, {}
SET quelle = "Hier der Name derQuelldatei"
SET ziel = "Hier der Name der Zieldatei"
SET anzahl = RECORDS($quelle)
PRINT "Die Datei {quelle} hat {anzahl} Datensätze."
SET daten = FILE($quelle)
SET daten = JOIN(daten, "")
SET anzahl = SIZE(daten)
PRINT "Die Variable daten hat jetzt nur noch {anzahl} Zeile(n)."
FILE/ERASE ziel = daten
*eof
]]> Eine Frage aus der TUSTEP Nutzergemeinde: Ich möchte alle Sätze einer Tustep-Datei in einen einzigen Satz schreiben, ohne dabei mit AA den Abschnittsanfang angeben zu müssen. Geht das?

Mit TUSCRIPT ist das sehr einfach möglich:

1. Laden des Datei-Inhalts in eine Sternvariable:

Code:

SET daten = FILE(quelle)


2. Reduzieren der Sternvariable auf eine einfache Variable mit der Funktion JOIN:

Code:

SET daten = JOIN(daten, "")

Anmerkung: Man kann auch Trennzeichen angeben, z. B. " " oder ";" oder eben nichts "".

3. Speichern des Variablen-Inhalts in eine Datei

Code:

FILE/ERASE ziel = daten


Hier ein vollständiges Musterprogramm:

Code:

#MAKRO
$$ MODE TUSCRIPT, {}
SET quelle = "Hier der Name der Quelldatei"
SET ziel = "Hier der Name der Zieldatei"
SET daten = FILE($quelle)
SET daten = JOIN(daten, "")
FILE/ERASE ziel = daten
*eof

Sehr nützlich in diesem Zusammenhang sind die TUSCRIPT-Funktionen RECORDS und SIZE, um zu kontrollieren, ob ein JOIN wie erwartet funktioniert hat.
Mit diesen kann die Anzahl der Datensätze einer Datei abgefragt werden (Records) oder die Anzahl der Zeilen in einer Sternvariable (SIZE), z. B.:

Code:

#MAKRO
$$ MODE TUSCRIPT, {}
SET quelle = "Hier der Name derQuelldatei"
SET ziel = "Hier der Name der Zieldatei"
SET anzahl = RECORDS($quelle)
PRINT "Die Datei {quelle} hat {anzahl} Datensätze."
SET daten = FILE($quelle)
SET daten = JOIN(daten, "")
SET anzahl = SIZE(daten)
PRINT "Die Variable daten hat jetzt nur noch {anzahl} Zeile(n)."
FILE/ERASE ziel = daten
*eof
]]>